113 lines
4.0 KiB
CMake
113 lines
4.0 KiB
CMake
# Copyright (C) 2018-2021 Intel Corporation
|
|
# SPDX-License-Identifier: Apache-2.0
|
|
#
|
|
|
|
cmake_minimum_required (VERSION 3.13)
|
|
|
|
project (pyngraph)
|
|
|
|
if(NOT DEFINED OpenVINO_SOURCE_DIR)
|
|
find_package(InferenceEngineDeveloperPackage QUIET)
|
|
find_package(ngraph REQUIRED)
|
|
endif()
|
|
|
|
add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/pybind11 EXCLUDE_FROM_ALL)
|
|
|
|
# PYTHON_VERSION_MAJOR and PYTHON_VERSION_MINOR are defined inside pybind11
|
|
set(PYTHON_VERSION python${PYTHON_VERSION_MAJOR}.${PYTHON_VERSION_MINOR})
|
|
message(STATUS "Python version=${PYTHON_VERSION}")
|
|
|
|
set(LIBRARY_OUTPUT_DIRECTORY_BIN ${CMAKE_LIBRARY_OUTPUT_DIRECTORY})
|
|
if(OpenVINO_SOURCE_DIR)
|
|
if(WIN32)
|
|
set(PYTHON_BRIDGE_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/$<CONFIG>/python_api/${PYTHON_VERSION}/)
|
|
else()
|
|
set(PYTHON_BRIDGE_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/python_api/${PYTHON_VERSION}/)
|
|
endif()
|
|
|
|
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PYTHON_BRIDGE_OUTPUT_DIRECTORY})
|
|
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PYTHON_BRIDGE_OUTPUT_DIRECTORY})
|
|
set(CMAKE_COMPILE_PDB_OUTPUT_DIRECTORY ${PYTHON_BRIDGE_OUTPUT_DIRECTORY})
|
|
set(CMAKE_PDB_OUTPUT_DIRECTORY ${PYTHON_BRIDGE_OUTPUT_DIRECTORY})
|
|
endif()
|
|
|
|
# compile options
|
|
|
|
if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
|
|
# disable warning: This operator was deprecated and will be removed with v0 operation.
|
|
add_compile_options(/wd4996)
|
|
elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
|
|
add_compile_options(-Wno-deprecated-register -Wno-range-loop-analysis)
|
|
elseif(CMAKE_CXX_COMPILER_ID STREQUAL "AppleClang")
|
|
add_link_options(-stdlib=libc++)
|
|
add_compile_options(-Wno-unused-value -Wno-range-loop-analysis)
|
|
elseif(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
|
|
# WA for GCC 7.5 "PYBIND11_NOINLINE inline" warning
|
|
add_compile_options(-Wno-error=attributes)
|
|
endif()
|
|
|
|
if(NOT CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
|
|
# for proper fix need to update pybind to version which does not use PyEval_InitThreads()
|
|
add_compile_options(-Wno-deprecated-declarations -Wno-undef)
|
|
endif()
|
|
|
|
# create target
|
|
|
|
file(GLOB_RECURSE SOURCES src/pyngraph/*.cpp)
|
|
|
|
pybind11_add_module(_${PROJECT_NAME} MODULE ${SOURCES})
|
|
|
|
target_include_directories(_${PROJECT_NAME} PRIVATE "${CMAKE_CURRENT_SOURCE_DIR}/src")
|
|
|
|
target_link_libraries(_${PROJECT_NAME} PRIVATE ngraph::ngraph ngraph::frontend_manager)
|
|
|
|
if (TARGET ngraph::onnx_importer)
|
|
add_dependencies(_${PROJECT_NAME} ngraph::onnx_importer)
|
|
endif()
|
|
|
|
if(NGRAPH_UNIT_TEST_ENABLE)
|
|
add_subdirectory(tests/mock/mock_py_ngraph_frontend)
|
|
add_dependencies(_${PROJECT_NAME} mock_py_ngraph_frontend)
|
|
set_target_properties(mock_py_ngraph_frontend PROPERTIES
|
|
LIBRARY_OUTPUT_DIRECTORY ${LIBRARY_OUTPUT_DIRECTORY_BIN}
|
|
ARCHIVE_OUTPUT_DIRECTORY ${LIBRARY_OUTPUT_DIRECTORY_BIN}
|
|
COMPILE_PDB_OUTPUT_DIRECTORY ${LIBRARY_OUTPUT_DIRECTORY_BIN}
|
|
PDB_OUTPUT_DIRECTORY ${LIBRARY_OUTPUT_DIRECTORY_BIN})
|
|
|
|
add_subdirectory(tests/mock/pyngraph_fe_mock_api)
|
|
add_dependencies(_${PROJECT_NAME} pybind_mock_frontend)
|
|
endif()
|
|
|
|
# perform copy
|
|
if(OpenVINO_SOURCE_DIR)
|
|
add_custom_command(TARGET _${PROJECT_NAME}
|
|
POST_BUILD
|
|
COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/src/ngraph ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/ngraph
|
|
)
|
|
endif()
|
|
|
|
if(OpenVINO_SOURCE_DIR OR InferenceEngineDeveloperPackage_FOUND)
|
|
if(COMMAND ie_python_minimal_api)
|
|
ie_python_minimal_api(_${PROJECT_NAME})
|
|
endif()
|
|
|
|
add_clang_format_target(_${PROJECT_NAME}_clang FOR_TARGETS _${PROJECT_NAME})
|
|
|
|
ie_cpack_add_component(pyngraph_${PYTHON_VERSION})
|
|
|
|
install(TARGETS _${PROJECT_NAME}
|
|
DESTINATION python/${PYTHON_VERSION}
|
|
COMPONENT pyngraph_${PYTHON_VERSION})
|
|
|
|
install(DIRECTORY ${CMAKE_CURRENT_LIST_DIR}/src/ngraph
|
|
DESTINATION python/${PYTHON_VERSION}
|
|
COMPONENT pyngraph_${PYTHON_VERSION}
|
|
USE_SOURCE_PERMISSIONS)
|
|
|
|
install(DIRECTORY ${CMAKE_CURRENT_LIST_DIR}/tests
|
|
DESTINATION tests/${PROJECT_NAME}
|
|
COMPONENT tests EXCLUDE_FROM_ALL)
|
|
|
|
ie_cpack(pyngraph_${PYTHON_VERSION})
|
|
endif()
|